Информатика. Книга 7 Быстрое размножение рабочей книги 7 Сохранение рабочей книги с именем, представляющим собой текущую дату 7

• Название: Книга 7 Быстрое размножение рабочей книги 7 Сохранение рабочей книги с именем, представляющим собой текущую дату 7
• Анкор: Информатика
• Дата: 16.05.2022
• Размер: 1.27 Mb.
• Имя файла: VBA_v_primerakh.doc
• Тип: Книга; #532661
• страница: 8 из 21

Дополнение панели инструментов

Листинг 3.40. Дополнение панели инструментов

Sub AddCustomCommandBar()

' Добавление кнопки на панель инструментов

With Application.CommandBars(3).Controls.Add(Type:=msoControlButton)

.FaceId = 42 ' Значок Word

.Caption = "Кнопка"

.OnAction = "Макрос"

End With

End Sub

Листинг 3.41. Добавление кнопки на панель инструментов

Sub AddCustomButton()

' Добавление кнопки на панель инструментов

With Application.Toolbars(1).ToolbarButtons.Add(button:=222)

.Name = "Кнопка"

.OnAction = "Макрос"

End With

End Sub

Примеры создания панелей инструментов

Листинг_3.42.'>Листинг 3.42. Панель с одной кнопкой

Sub CreateCustomControlBar()

' Создание панели инструментов

With Application.CommandBars.Add(Name:="Панель", Temporary:=True)

' Создание и настройка кнопки

With .Controls.Add(Type:=msoControlButton)

.Style = msoButtonIconAndCaption

.FaceId = 66

.Caption = "Просто кнопка"

End With

' Покажем панель

.Visible = True

End With

End Sub

Листинг 3.43. Панель с двумя кнопками

Sub CreateCustomControlBar()

' Создание панели инструментов

With Application.CommandBars.Add(Name:="Панель", Temporary:=True, _

Position:=msoBarLeft)

' Создание и настройка первой кнопки

With .Controls.Add(Type:=msoControlButton)

.Style = msoButtonWrapCaption

.Caption = "Просто кнопка"

End With

' Создание и настройка второй кнопки

With .Controls.Add(Type:=msoControlButton)

.Style = msoButtonIconAndWrapCaption

.Caption = "Кнопка"

.FaceId = 225

End With

' Покажем панель

.Visible = True

End With

End Sub

Листинг 3.44. Создание панели справа

Sub CreateCustomControlBar()

' Создание панели инструментов

With Application.CommandBars.Add(Name:="Правая панель", _

Temporary:=True)

' Создание и настройка кнопки

With .Controls.Add(Type:=msoControlButton)

.Style = msoButtonWrapCaption

.Caption = "Кнопка"

End With

' Задание позиции - справа

.Position = msoBarRight

' Покажем панель

.Visible = True

End With

End Sub

Формирование пользовательского меню

Листинг 3.45. Создание пользовательского меню (вариант 1)

Sub AddCustomMenu()

' Добавление меню

With Application.CommandBars(1).Controls.Add(Type:=msoControlPopup, _

Temporary:=True)

.Caption = "Архив"

With .Controls

' Добавление и настройка первого пункта

With .Add(Type:=msoControlButton)

.FaceId = 280

.Caption = "Просмотр"

.OnAction = "Макрос1"

End With

' Добавление вложенного меню

With .Add(Type:=msoControlPopup)

.Caption = "База данных"

With .Controls

' Добавление и настройка первого пункта _

вложенного меню

With .Add(Type:=msoControlButton)

.FaceId = 1643

.Caption = "Поставщики"

.OnAction = "Макрос2"

End With

' Добавление и настройка второго пункта _

вложенного меню

With .Add(Type:=msoControlButton)

.FaceId = 1000

.Caption = "Покупатели"

.OnAction = "Макрос3"

End With

End With

End With

End With

End With

End Sub

Листинг 3.46. Создание пользовательского меню (вариант 2)

Sub AddCustomMenu1()

' Добавление меню с названием "Архив" в часть меню, _

относящуюся к рабочей книге

With MenuBars("Worksheet").Menus.Add(Caption:="Архив")

' Добавление кнопки

.MenuItems.Add Caption:="Просмотр", OnAction:="Макрос1"

' Добавление подменю

With .MenuItems.AddMenu(Caption:="База данных")

' Добавление пунктов подменю

.MenuItems.Add Caption:="Поставщики", OnAction:="Макрос2"

.MenuItems.Add Caption:="Покупатели", OnAction:="Макрос3"

End With

End With

End Sub

Листинг 3.47. Создание пользовательского меню (вариант 3)

Sub AddCustomMenu2()

' Добавление меню с названием "Архив" в часть меню, _

относящуюся к рабочей книге

With MenuBars("Worksheet").Menus.Add(Caption:="Архив")

' Добавление кнопки

.MenuItems.Add Caption:="Просмотр", OnAction:="Макрос1"

' Добавление подменю

With .MenuItems.AddMenu(Caption:="База данных")

' Добавление первого пункта подменю

With .MenuItems.Add(Caption:="Поставщики")

' Настройка кнопки

.OnAction = "Макрос2"

End With

' Добавление второго пункта подменю

With .MenuItems.Add(Caption:="Покупатели")

' Настройка кнопки

.OnAction = "Макрос3"

End With

End With

End With

End Sub