Практическая работа 1-8 2022. Программа для работы в tcad под ос windows есть на кафедре (до 500 Мб). Есть версия под 2015 год

• Название: Программа для работы в tcad под ос windows есть на кафедре (до 500 Мб). Есть версия под 2015 год
• Анкор: ghfrnbrf
• Дата: 15.05.2022
• Размер: 2.17 Mb.
• Имя файла: Практическая работа 1-8 2022.docx
• Тип: Программа; #531273

ПРАКТИЧЕСКИЕ РАБОТЫ ПО ДИСЦИПЛИНЕ

КВАНТОВАЯ МЕХАНИКА И СТАТИСТИЧЕСКАЯ ФИЗИКА

Общая информация

Программа для работы в TCAD под ОС Windows есть на кафедре (до 500 Мб). Есть версия под 2015 год.

Версия от 2018 года есть по ссылкам:

https://goo.gl/fIUYnq

https://majhar.wordpress.com/silvaco-tutorial/
Есть более новые версии программы, например у арабов (2019 год): https://downloadly.ir/software/engineering-specialized/silvaco-tcad/

Остальные версии смотрите в сети сами.

Рис. 0. Ссылка на программу в сети

Установка и присоединение ключ-файла должны выполняться строго по инструкции из прилагаемого pdf-файла. В используемой версии (рис. 1) нет блоков victory (process, device, stress), поэтому не все проекты для студентов магистерских программ будут работать в данной версии. Обязательно запоминайте придуманный вами пароль для входа в настройку лицензии (лучше устанавливать пароль 123).

Рис. 1. Путь к программе в коневом каталоге ОС Windows

Основное рабочее окно, в котором будет создаваться проект, запускается в папке «SedaTools» щелчком на ярлыке «DeckBuild».

По щелчку открывается окно, состоящее из нескольких блоков:

– область для написания кода структуры,

– окно для выведения лог-файла во время расчёта,

– окно, в котором будут выведены данные по рассчитываемым переменным,

– окно, в котором выводится набор файлов рассчитанных структур и графиков,

– область мониторинга ресурсов системы.

Проверка работоспособности установленного ПО (рис. 2, 3):

Рис. 2. Основное окно программы

– File – Examples: – открывается окно с набором встроенных готовых проектов, в котором выбирается проект из блока Product – Athena; описание проекта видно при щелчке на названии;

– выбираем «load»;

Рис. 3. Путь запуска примеров расчёта моделей TCAD

– в основном окне кода будет загружен текст проекта; обратите внимание на цветовые обозначения элементов текста:

сиреневый (начинается со слова «go », используется всегда) – указание на решающий модуль (Athena, Atlas, DevEdit, Internal – кстати, на диске С в папке «C:\sedatools\lib» расположены папки с мануалами pdf по этим модулям, названия совпадают),

розовый (начинается со слова «set », используется не во всех кодах) – задание переменной / переменных (в коде будут использованы ссылки со знаками ${ }),

чёрный основной текст кода,

синий – те самые ссылки на переменные,

зеленый (начинается с знака «#») – это комментарии, то, что написано в них, никак не будет учитываться программой при расчёте,

зелено-голубой – цифры,

чёрный полужирный (начинается со слова «extract », используется не во всех кодах) – формула для расчёта или экстракции какого-то параметра структуры;

– запуск кода на выполнение осуществляется щелчком на кнопке «play» (зеленый треугольник в верхнем левом углу);

– при выполнении кода просчитываемая строка подсвечена желтым, а сам расчёт выводится в нижней части экрана (рис. 4):

синий – текст кода команды,

черный – сам лог расчёта,

розовый – экстракция какого то значения командой «extract ».

Рис. 4. Пример отображения окна при выполнении кода программы

Модули TonyPlot и TonyPlot3D отвечают за вывод рассчитанных характеристик и структур – в версии под Windows могут выдавать ошибку загрузки.

Методы запуска рассчитанных структур и графиков показаны на рис. 5 и 6.

Рис. 5. Модули вывода на экран графических результатом моделирования в папке с программой

Рис. 6. Вывод графических данных непосредственно из кода программы

Когда откроется окно графика (тип файла .log), его необходимо настроить для правильного отображения (рис. 7, 8). ПКМ на графике – Display – откроется окно настройки осей графика. По оси Х можно задать 1 переменную, по оси Y – несколько. Масштаб может быть линейным, логарифмическим, можно построить график в полярной системе координат. Масштабирование можно осуществлять мышью, тогда вверху слева появится область управления или через настройки графика.

Можно открывать несколько графиков на одном (File – Open, внизу выбираем OverLay) или в соседних областях окна (File – Open, внизу выбираем Add).

Рис. 7. Отображение графиков в программе

Рис. 8. Настройки отображения графиков

При работе со структурами (тип файла .str) нажимаем ПКМ и выбираем пункт Display, который позволяет настроить отображение сетки, контуров областей, материалов структуры, концентрации носителей заряда, границ p-n переходов, электродов (остальные настройки в рамках курса не понадобятся) – основные элементы управления приведены на рис. 9, 10.

При активном параметре распределения носителей заряда (по умолчанию – распределение концентрации носителей заряда без деления по типу) для настройки различных распределений необходимо выбрать в окне настройки выпадающий список Define – Contours; откроется окно, в котором основным элементом будет выпадающий список Quantity, в котором выбираются требуемые распределения.

Рис. 9. Первый шаг настройки отображения структур

Рис. 10. Второй шаг настройки отображения структур

ВАЖНО!

Каждый проект необходимо сохранять в отдельную папку (если в одном задании делается несколько расчётов, то или каждый расчёт или должен находиться в своей папке, или вариации параметра будут заданы блоком «set» в коде).

Чтобы код программы, написанный в ОС Windows, без проблем сохранялся и отображал нечитаемые символы, используйте англоязычные пути к файлу решаемой задачи.

Комментарии в коде рекомендуется писать английскими символами или дублировать в файле типа «.docx», так как из исходного файла типа «.in» они часто «слетают», превращаясь в «#????????? ???».

Файл «.in» можно открывать обычным Блокнотом или WordPadом.

Файлы «.str» и «.log» открываются только в модуле TonyPlot (или TonyPlot 3D), поэтому для формирования отчёта по поставленной задаче требуется делать снимки экрана (printscreen) с отображенными графиками или структурами.
Если программа под ОС Win не устанавливается на конкретный ПК, можно использовать вариант TCAD для виртуальной машины, который «весит» порядка 29 Гб. Папку с программой можно сохранить на флеш-карту (64 Гб) или внешний жесткий диск. Система, под которую программа устанавливается, должна иметь размерность 64 бита. Оперативная память – не меньше 4 Гб, половина из которых отдается под загрузку виртуального образа с системой.

Оболочка VMWare (можно использовать WorkStation или Player) имеет размер порядка 50 Мб, рекомендуется использовать последнюю версию программы. Пароль на вход в систему на виртуальной машине: 12345. В системе открываем папку S.EDA Tools, запускаем ярлык DeckBuild (рис. 11).

Рис. 11. Внешний вид окна программы, запущенного под виртуальной машиной

Зеленый треугольник – запуск кода на выполнение.

Путь «File – Examples» открывает каталог с примерами кода для различных структур.

Путь «Home - ↑ - ↑ - opt – silvaco – lib – (папки)» дает выход на файлы с описанием модулей, содержащихся в TCAD. Нам нужны: Athena, Atlas, DeckBuild, TonyPlot, TonyPlot3D, VictoryProcess, VictoryDevice. Нужные файлы лежат в подпапках «docs» и содержат в названии «_users1».

Практическая работа 1-2
ВФХ p-МОП конденсатора с тонким подзатворным окислом

Задание:

1. 
   Запустите код из данного файла. Изучите его структуру по словам. Получите графики, аналогичные указанным в описании примера в программе.
   
2. 
   Корректно переведите описание структуры конденсатора, приведенного в пояснении к задаче (текст приведен ниже).
   
3. 
   Используя разобранный на практике код, опишите порядок построения и моделирования прибора. Добавьте в отчёт получившиеся рисунки с описанием того, что на них отображено.
   
4. 
   Найдите реально существующие аналогичные приборы (статьи в google, поисковый запрос лучше формировать на английском языке, в конце запроса «(пробел) pdf», чтобы в основном выгружались статьи).
   
5. 
   Попробуйте изменить в сторону уменьшения и увеличения какой-либо параметр структуры. Опишите, что получилось.
   
6. 
   Определите по коду, какой параметр отвечает за квантовые эффекты при моделировании структуры. Опишите его.
   
7. 
   Корректно переведите и изучите блок, описывающий модель, использующую этот параметр (путь к файлу, на Ваших машинах может быть другим: C:\sedatools\lib\atlas\5.28.1.R\docs)
   

Рис. 12. Глава в мануале, содержащая модели, с использованием которых строится та или иная задача

8. 
   Оформите всю работу в виде отчёта по правилам стандарта ВГТУ. Распечатайте, подпишите и сдайте на проверку.
   

Графики и структуры на рисунках приведены в качестве подсказки того, что Вы должны получить на рисунках. Сами графики, выгруженные в программе, придется «донастраивать», подбирая оси, масштаб и т.д.
CV Analysis Of Thin Gate Oxide PMOS Capacitor

This code demonstrates the CV characteristics of a N-type substrate MOS capacitor with a nominal 30A gate oxide. The example shows:

1. 
   Calculation of CV curves using AC Analysis
   
2. 
   Use of the Quantum moments quantum model
   
3. 
   Difference between classical and quantum gate thickness
   
4. 
   Classical and Quantized electron density
   

A simple 1D MOS capacitor is created in this example with a 30A gate oxide thickness. An AC analysis is performed on the device firstly with the classical simulation and the with the quantum model swtiched on.

The quantum model is activated by using the quantum switch in the models statement for electrons. Note that this activates a quantum moments model which uses a quantum temperature calculation. This quantum temperature can be viewed in the structure files. Also, the cutline created in TonyPlot can be used to examine the classical and quantum electron concentration differences in the structure.

In accumulation, the channel carrier concentration is changed by the addition of quantum mechanics. The peak is not so high and the electrons spread more deeply into the substrate. The difference in gate capacitance is noticable on the CV plot. Since gate oxide thickness is often measured using CV techniques, this leads to erroneous results if QM effects are not accounted for. extract statements are used to show the calculated Tox from the classical and QM CV curves.
go atlas
mesh
x.m l=0 spac=1

x.m l=1 spac=1
y.m l=-0.0035 spac=0.001

y.m l=0 spac=0.0001

y.m l=0.1 spac=0.02

y.m l=0.5 spac=0.2
region num=1 silicon y.min=0

region num=2 oxide y.max=0
electrode name=gate top

electrode substrate
doping uniform conc=1e17 n.type

save outf=capacitorPMOS.str
go atlas
mesh inf=capacitorPMOS.str

contact name=gate n.poly

models cvt srh print

output con.band val.band t.quantum
method carr=2 maxtrap=10

solve outfile=capacitorPMOS_temp.str master

log outf=capacitorPMOS_1.log

solve vgate=0 vstep=0.1 vfinal=5 name=gate ac freq=1e6 direct

save outf=capacitorPMOS_1.str

log off
load infile=capacitorPMOS_temp.str master

solve

log outf=capacitorPMOS_2.log

solve vgate=0 vstep=-0.2 vfinal=-2 name=gate ac freq=1e6 direct

save outf=capacitorPMOS_2.str
go atlas
mesh inf=capacitorPMOS.str

contact name=gate n.poly

models cvt srh print quantum

output con.band val.band t.quantum
method carr=2 maxtrap=10

solve outfile=capacitorPMOS_temp.str master

log outf=capacitorPMOS_3.log

solve vgate=0 vstep=0.1 vfinal=5 name=gate ac freq=1e6 direct

save outf=capacitorPMOS_3.str

log off
load infile=capacitorPMOS_temp.str master

solve

log outf=capacitorPMOS_4.log

solve prev vgate=0 vstep=-0.1 vfinal=-2 name=gate ac freq=1e6 direct

save outf=capacitorPMOS_4.str
tonyplot -overlay capacitorPMOS_1.log capacitorPMOS_2.log capacitorPMOS_3.log capacitorPMOS_4.log -set capacitorPMOS_1.set

tonyplot -overlay capacitorPMOS_1.str capacitorPMOS_3.str -set capacitorPMOS_2.set
extract init inf="capacitorPMOS_1.log"

extract name="tox_cl" (3.9*8.85e-10*1.0e-4)/max(c."gate""substrate")

extract init inf="capacitorPMOS_3.log"

extract name="tox_qm" (3.9*8.85e-10*1.0e-4)/max(c."gate""substrate")
quit
Итоговые структуры и зависимости с установленными настройками:

Рис. 13. ВФХ диода

Рис. 14. Распределение (чего? – найдите сами)

Практическая работа 3–4
Утечки в диоде на гетеропереходах

Задание:

1. 
   Запустите код из данного файла. Изучите его структуру по словам. Получите графики, аналогичные указанным в описании примера в программе.
   
2. 
   Корректно переведите описание структуры конденсатора, приведенного в пояснении к задаче (текст приведен ниже).
   
3. 
   Используя разобранный на практике код, опишите порядок построения и моделирования прибора. Добавьте в отчёт получившиеся рисунки с описанием того, что на них отображено.
   
4. 
   Найдите реально существующие аналогичные приборы (статьи в google, поисковый запрос лучше формировать на английском языке, в конце запроса «(пробел) pdf», чтобы в основном выгружались статьи).
   
5. 
   Попробуйте изменить в сторону уменьшения и увеличения какой-либо параметр структуры. Опишите, что получилось.
   
6. 
   Определите по коду, какой параметр отвечает за квантовые эффекты при моделировании структуры. Опишите его.
   
7. 
   Корректно переведите и изучите блок, описывающий модель, использующую этот параметр (путь к файлу, на Ваших машинах может быть другим: C:\sedatools\lib\atlas\5.28.1.R\docs)
   
8. 
   Оформите всю работу в виде отчёта по правилам стандарта ВГТУ. Распечатайте, подпишите и сдайте на проверку.
   

Графики и структуры на рисунках приведены в качестве подсказки того, что Вы должны получить на рисунках. Сами графики, выгруженные в программе, придется «донастраивать», подбирая оси, масштаб и т.д.
Heterojunction Diode Leakage
This code demonstrates the difference between an AlGaAs / GaAs heterojunction diode modeled with and without quantum physics.

In the first half of the file, the example calculates the forward and reverse characteristics of a classically modeled diode. In the second half of the example, the quantum model is switched on. Note that, as in the previous example, the qfactor is used to ramp the level of quantum moments included in the example for zero to unity.

The overlayed results show around an order of magnitude higher reverse leakage in the quantum case. This is due to the smearing of the electron concentration across the heterojunction.
go atlas
mesh
x.m l=0 spac=1

x.m l=1 spac=1
y.m l=0.000 spac=0.1

y.m l=0.5 spac=0.0001

y.m l=1.0 spac=0.1
region num=1 material=GaAs

region num=2 material=AlGaAs y.min=0.000 y.max=0.4995 x.comp=0.8 grad.34=0.0005
electrode name=anode top

electrode name=cathode bottom
doping uniform conc=1e14 n.type
models fldmob srh print
material material=AlGaAs align=0.6

output band.param val.band con.band
method carr=1 elec newton
solve vanode=0.00 outf=geterDiode_temp.str master
log outf=geterDiode_1.log

solve vanode=0 vstep=0.1 vfinal=2 name=anode
log outf=geterDiode_2.log

load inf=geterDiode_temp.str master

solve vanode=0 vstep=-0.1 vfinal=-2 name=anode

save outf=geterDiode_1.str
go atlas
mesh
x.m l=0 spac=1

x.m l=1 spac=1
y.m l=0.000 spac=0.1

y.m l=0.5 spac=0.0001

y.m l=1.0 spac=0.1
region num=1 material=GaAs

region num=2 material=AlGaAs y.min=0.000 y.max=0.4995 x.comp=0.8 grad.34=0.0005
electrode name=anode top

electrode name=cathode bottom
doping uniform conc=1e14 n.type
models fldmob srh print quantum
material material=AlGaAs align=0.6

output t.quantum band.param val.band con.band
method carr=1 elec newton

solve qfactor=0

solve qfactor=0.01

solve qfactor=0.05

solve qfactor=0.1

solve qfactor=0.2

solve qfactor=0.3

solve qfactor=0.4

solve qfactor=0.5

solve qfactor=0.6

solve qfactor=0.7

solve qfactor=1.0 outfile=geterDiode_temp.str master
log outf=geterDiode_3.log

solve vanode=0 vstep=0.1 vfinal=2 name=anode
log outf=geterDiode_4.log

load inf=geterDiode_temp.str master

solve vanode=0 vstep=-0.1 vfinal=-2 name=anode

save outf=geterDiode_2.str
tonyplot -overlay geterDiode_1.log geterDiode_2.log geterDiode_3.log geterDiode_4.log -set geterDiode_1.set
quit

Рис.15. Сравнение квантовой и классической моделей
(укажите, где какая?)

Практическая работа 5–6
Квантовое туннелирование в кремниевом диоде

Задание:

1. 
   Запустите код из данного файла. Изучите его структуру по словам. Получите графики, аналогичные указанным в описании примера в программе.
   
2. 
   Корректно переведите описание структуры конденсатора, приведенного в пояснении к задаче (текст приведен ниже).
   
3. 
   Используя разобранный на практике код, опишите порядок построения и моделирования прибора. Добавьте в отчёт получившиеся рисунки с описанием того, что на них отображено.
   
4. 
   Найдите реально существующие аналогичные приборы (статьи в google, поисковый запрос лучше формировать на английском языке, в конце запроса «(пробел) pdf», чтобы в основном выгружались статьи).
   
5. 
   Попробуйте изменить в сторону уменьшения и увеличения какой-либо параметр структуры. Опишите, что получилось.
   
6. 
   Определите по коду, какой параметр отвечает за квантовые эффекты при моделировании структуры. Опишите его.
   
7. 
   Корректно переведите и изучите блок, описывающий модель, использующую этот параметр (путь к файлу, на Ваших машинах может быть другим: C:\sedatools\lib\atlas\5.28.1.R\docs)
   
8. 
   Оформите всю работу в виде отчёта по правилам стандарта ВГТУ. Распечатайте, подпишите и сдайте на проверку.
   

Графики и структуры на рисунках приведены в качестве подсказки того, что Вы должны получить на рисунках. Сами графики, выгруженные в программе, придется «донастраивать», подбирая оси, масштаб и т.д.
Quantum Tunnelling in a Silicon Diode

Example of a QTREGION statement.

Example of BBT.NONLOCAL and BBT.NLDERIVS commands.

In this code, the QTREGION statement is used to set up a mesh suitable for tunneling calculations. The device is a degenerately doped silicon p-n diode. Non-local Band-To-Band tunneling is selected on the MODELS statement by using the BBT.NONLOCAL keyword. Because the solution will go to relatively high levels of tunneling current, convergence may become difficult. The optional parameter BBT.NLDERIVS is used to improve this. The diode is biased into both forward and reverse biases. In forward bias a tunneling current occurs up to about 0.3 V, and at higher bias the usual forward bias diffusion current occurs as can be seen in the LOG file. The STRUCTURE files, with the BBT tunneling current displayed, show the actual tunneling current being injected into the device. Under reverse bias it acts like generation, under forward bias like recombination.
go atlas
mesh space.mult=1.0 ^diag.flip
# параметр масштабирования сетки «mesh space.mult» позволяет глобально задать множитель, который будет использоваться при построении сетки для расчета структуры
x.mesh location=0.0 spacing=0.5

x.mesh location=1.0 spacing=0.5
y.mesh loc=0 spacing=0.1

y.mesh loc=0.9 s=0.05

y.mesh loc=0.95 s=0.001

y.mesh loc=1.05 s=0.001

y.mesh loc=1.1 s=0.05

y.mesh loc=2 spacing=0.1
# определение геометрических размеров структуры по оси Х\Y и шага сетки по оси Х\Y
region num=1 material=silicon
# материал первой области – кремний
elec name=anode top

elec name=cathode bottom
qtregion number=1 pts.normal=3 pts.tunnel=131 x1=0.0 y1=0.95 x2=1.0 y2=0.95 x3=1.0 y3=1.05 x4=0.0 y4=1.05
# QTREGION используется для настройки сетки, подходящей для вычислений туннелирования. Здесь мы настраиваем область квантового туннелирования.
doping uniform p.type conc=2e20 y.max=1.0
doping uniform n.type conc=2e20 y.min=1.0
# легирование примесью p-типа\n-типа заданной концентрации для формирования защитного кольца,
models temperature=200 srh fermi ni.fermi print bbt.nonlocal bbt.nlderivs
# Зависимость уровня Ферми от температуры. bbt.forward и bbt.nl derived параметры позволяют использовать нелокальнуюмодель межполосного туннелирования при прямом смещении и позволяют использовать нелокальные производные в матрице Якоби, что помогает устранить проблемы сходимости.
output band.temp traps u.srh
# Определение выходных значений моделирования
method climit=1.0 dvmax=0.005

solve init

# начало расчета

# CLIMIT задает минимальные значения концентрации носителей заряда для расчета. DVMAX определяет максимальный шаг изменения потенциала на каждую итерацию в методе Ньютона.



log outf=tunnelSiDiode_reverse.log
solve name=anode vanode=-0.0 vstep=-0.01 vfinal=-0.05

solve name=anode vanode=-0.05 vstep=-0.05 vfinal=-0.2

solve name=anode vanode=-0.25 vstep=-0.05 vfinal=-0.5

log off
solve init

log outf=tunnelSiDiode_forward.log
solve name=anode vanode=0.0 vstep=0.005 vfinal=0.2

solve name=anode vanode=0.205 vstep=0.005 vfinal=0.35

solve name=anode vanode=0.375 vstep=0.025 vfinal=1.2
# загрузка информации по напряжениям на аноде
tonyplot -overlay tunnelSiDiode_forward.log tunnelSiDiode_reverse.log -set tunnelSiDiode.set
exit

Рис. 16. Прямая и обратная ветви ВАХ (чего?)

Практическая работа 7–8
РТД p-типа на SiGe

Задание:

9. 
   Запустите код из данного файла. Изучите его структуру по словам. Получите графики, аналогичные указанным в описании примера в программе.
   
10. 
    Корректно переведите описание структуры конденсатора, приведенного в пояснении к задаче (текст приведен ниже).
    
11. 
    Используя разобранный на практике код, опишите порядок построения и моделирования прибора. Добавьте в отчёт получившиеся рисунки с описанием того, что на них отображено.
    
12. 
    Найдите реально существующие аналогичные приборы (статьи в google, поисковый запрос лучше формировать на английском языке, в конце запроса «(пробел) pdf», чтобы в основном выгружались статьи).
    
13. 
    Попробуйте изменить в сторону уменьшения и увеличения какой-либо параметр структуры. Опишите, что получилось.
    
14. 
    Определите по коду, какой параметр отвечает за квантовые эффекты при моделировании структуры. Опишите его.
    
15. 
    Корректно переведите и изучите блок, описывающий модель, использующую этот параметр (путь к файлу, на Ваших машинах может быть другим: C:\sedatools\lib\atlas\5.28.1.R\docs)
    
16. 
    Оформите всю работу в виде отчёта по правилам стандарта ВГТУ. Распечатайте, подпишите и сдайте на проверку.
    

Графики и структуры на рисунках приведены в качестве подсказки того, что Вы должны получить на рисунках. Сами графики, выгруженные в программе, придется «донастраивать», подбирая оси, масштаб и т.д.
SiGe p-type Resonant Tunneling Diode

This example considers a p-type SiGe RTD with 2nm wide double Si barriers separated by a 2nm SiGe well. A two-band model is used for hole bandstructure. Band offsets and effective masses are set by DEV.HH, DEV.LH and MHH, MLH parametrs on the MATERIAL statment. The convergence criterium for the maximum change in potential is set by the QCRIT.NEGF parameter on the MODELS statement to 0.1 meV.

In order to solve for eigen energies and wavefunctions, we use NEGF.EIG paramater of the SOLVE and SAVE statement. NEGF.EIG can be switchedoff to save computation time if the information on eigen energies is not required. Use EIG.YMIN and EIG.YMAX parametrs on the models statement to choose only states localized in this region.
go atlas
# p-type SiGe RTD example 2nm-2nm-2nm double barrier,
mesh diag.flip
x.mesh loc=0.00 spac=0.01

x.mesh loc=0.01 spac=0.01
y.mesh loc=-0.072 spac=0.0005

y.mesh loc=-0.01 spac=0.0002

y.mesh loc=0.0 spac=0.0001

y.mesh loc=0.011 spac=0.0001

y.mesh loc=0.013 spac=0.0001

y.mesh loc=0.015 spac=0.0001

y.mesh loc=0.017 spac=0.0001

y.mesh loc=0.024 spac=0.0001

y.mesh loc=0.026 spac=0.0001

y.mesh loc=0.036 spac=0.0001

y.mesh loc=0.046 spac=0.0002

y.mesh loc=0.1 spac=0.0005
# Source and drain regions have to be specified as EQUIL.NEGF to impose quasi-equilibrium condition.
region num=1 name=SiGe material=Si y.max=-0.01 equil.negf

region num=2 name=SiGe material=Si x.comp=0.6 y.min= -0.01 y.max=0.011 equil.negf

region num=3 name=Si material=Si y.min=0.011 y.max=0.013

region num=4 name=SiGe material=Si x.comp=0.6 y.min=0.013 y.max=0.015

region num=5 name=Si material=Si y.min=0.015 y.max=0.017

region num=6 name=SiGe material=Si x.comp=0.6 y.min=0.017 y.max=0.024

region num=7 name=SiGe material=Si x.comp=0.6 y.min=0.024 y.max=0.036 equil.negf

region num=8 name=SiGe material=Si y.min=0.036 y.max=0.046 equil.negf

region num=9 name=SiGe material=Si y.min=0.046 equil.negf
elec num=1 name=emitter top

elec num=2 name=collector bottom
doping reg=1 uniform p.type conc=1e18

doping reg=8 uniform p.type conc=1e16

doping reg=9 uniform p.type conc=1e18
# Band off-sets: We declare the same material Si in all regions. Here we modify band off-sets and set effective masses. Regions with SiGe are given a name "SiGe", and regions with Si are given a name "Si".

# Holes: when NUM.BAND>1 on MODELS statement, use DEV.HH,DEV.LH and DEV.SO to set band off-sets when NUM.BAND=1, use DEV.ISO to set band off-set for isotropic band

# Electrons: when NUM.DIRECT=3 on MODELS statement, use DEC.C1,DEC.C2 and DEC.C3 to set band off-sets for each pair of valleys.

# when NUM.DIRECT=1, use DEC.ISO to set band off-set for isotropic band (in this example we compute only hole transport, while electrons are treated clasically)

# Valence Band off-sets (from the highest Ev of bulk Si)
material name=Si dev.so=-0.044

material name=SiGe dev.hh=0.32 dev.lh=0.26 dev.so=-0.044
# Conduction Band off-sets (from the lowest Ec of bulk Si)

material name=SiGe dec.iso=-0.01
# Holes: when NUM.BAND=1, 1 band is assumed with effective mass MV

# when NUM.BAND=2, 2 bans are assumed with effective masses MHH and MLH

# when NUM.BAND=3, 3 bans are assumed with effective masses MHH and MLH and MSO

# Electrons: when NUM.DIRECT=1, 1 band is assumed with effective mass MC

# when NUM.DIRECT=3, 3 bands are assumed with anisotropic effective masses.

# (ML,MT1,MT2) for band#1,

# (MT1,ML,MT2) for band#2,

# (MT1,MT2,ML) for band#3,

# (in this example we compute only hole transport, while electrons are treated clasically)

# Effective masses (taken from http://www.ioffe.ru/SVA/NSM/Semicond/SiGe)
material name=Si mc=0.3 mhh=0.49 mlh=0.16 mso=0.24

material name=SiGe mc=1.06 mhh=0.426 mlh=0.1132 mso=0.17
# To launch model, use N.NEGF_PL1D and/or P.NEGF_PL1D on the MODELS statement. This will solve 1D model in one slice and copy it to all other slices. If slices are not equivalent, use N.NEGF_PL and/or P.NEGF_PL, to solve 1D model for each slice. Energy grid size in the NEGF solver is regulated by ESIZE.NEGF on the MODELS statement (default is 2001). You may increase it up to 10000 for better convergence. To set broadening in quazi-equilibrium regions use ETA.NEGF (default is 0.0066 eV). Increase it to 0.01 eV for better convergence. Physically, the broadening corresponds to inelastic electron-phonon scatterin, and is necessary to fill emitter quazi-bound states.

# P.NEGF_PL1D - only holes are taken into account in transport calculation

# Take only light and heavy holes into account by setting NUM.BAND=2

# ESIZE.NEGF=20001 incerases the number of energy grid for better resolution

# QCRIT.NEGF=1e-4 - convergence criterium is 0.1 meV or less in update of potential

# Broadening in quasi-equilibrium regions is set by ETA.NEGF=0.0066

# When storing for eigen energies and wave functions , take only ehose localized between EIG.YMIN=0.008 and EIG.YMAX=0.017
models p.negf_pl1d esize.negf=20001 eta.negf=0.0066 num.band=2 eig.ymin=0.008 eig.ymax=0.017 qcrit.negf=1e-4
method carr=0
# Probes contain important information about Transmission and density of states versus energy. Also, you can output DENSVSE (carrier density spectrum) and CURDVSE (current density spectrum). Files will have names RTDSiGe_TranvsE_0.log, RTDSiGe_TranvsE_1.log etc. for each time you set NEGF.LOG on the SAVE statement. Setting X-location is not needed if you solve only one slice (N.NEGF_PL1D).
probe transmission filename="RTDSiGe_TranvsE_"

probe transmission band=1

probe transmission band=2

probe dosvse x=0 y=0.015

probe dosvse x=0 y=0.015 band=1

probe dosvse x=0 y=0.015 band=2

probe curdvse x=0 y=0.015

probe curdvse x=0 y=0.015 band=1

probe curdvse x=0 y=0.015 band=2
# ESIZEOUT.NEGF on the OUTPUT statement is the size of energy grid in the output file TranvsE_DB2_0.log. If you don't set it, it will be the same as ESIZE.NEGF on the MODELS statement.
output con.band val.band eigen=7
solve init

save outf=RTDSiGe_init.str negf.log negf.eig
log outf=RTDSiGe_IV.log
solve v2=0 name=collector vstep=-0.02 vfinal=-0.1

save outf=RTDSiGe_vm01.str negf.log negf.eig
solve name=collector vstep=-0.02 vfinal=-0.2

save outf=RTDSiGe_vm02.str negf.log negf.eig
solve name=collector vstep=-0.02 vfinal=-0.3

save outf=RTDSiGe_vm03.str negf.log negf.eig
solve name=collector vstep=-0.02 vfinal=-0.4

save outf=RTDSiGe_vm04.str negf.log negf.eig
solve name=collector vstep=-0.005 vfinal=-0.5

save outf=RTDSiGe_vm05.str negf.log negf.eig
solve name=collector vstep=-0.005 vfinal=-0.58
solve name=collector vstep=-0.005 vfinal=-0.6

save outf=RTDSiGe_vm06.str negf.log negf.eig
solve name=collector vstep=-0.005 vfinal=-0.7

save outf=RTDSiGe_vm07.str negf.log negf.eig
solve name=collector vstep=-0.005 vfinal=-0.8

save outf=RTDSiGe_vm08.str negf.log negf.eig
solve name=collector vstep=-0.005 vfinal=-0.9

save outf=RTDSiGe_vm09.str negf.log negf.eig
solve name=collector vstep=-0.005 vfinal=-1

save outf=RTDSiGe_vm1.str negf.log negf.eig
solve name=collector vstep=-0.01 vfinal=-2

save outf=RTDSiGe_vm2.str negf.log negf.eig
log off
tonyplot RTDSiGe_vm07.str -set RTDSiGe_fig1.set

tonyplot RTDSiGe_vm07.str -set RTDSiGe_fig2.set

tonyplot RTDSiGe_IV.log -set RTDSiGe_fig3.set

tonyplot RTDSiGe_TranvsE_7.log -set RTDSiGe_fig4.set

tonyplot RTDSiGe_TranvsE_7.log -set RTDSiGe_fig5.set
quit


Рис. 17.



Рис. 18.





Рис. 19. Подобрать структуру самостоятельно (!!!)


Рис. 20.



Рис. 21.